
LetMe is an authorization library for Elixir that defines a Domain Specific
Language (DSL) for authorization rules.
Policy expressions are optimized at compile time and evaluated lazily using
Spek. It is possible to get the evaluated
part of the policy expression in the error case, which can be useful for
debugging, detailed error messages, or authorization decision logs.
The library also provides introspection functions that allow you to:
	List all authorization rules including their boolean expression tree for a
documentation page.
	Fetch an authorization rule by name.
	Filter authorization rules by subject, object, or checks that are applied.

Installation
Add LetMe to your list of dependencies in mix.exs:
def deps do
  [
    {:let_me, "~> 3.0.4"}
  ]
end
This package is tested against the Elixir and OTP versions that are still
supported upstream. Older versions down to the requirement in mix.exs may
still work, but they are not covered by CI and not officially supported.
Include LetMe in your .formatter.exs file:
[
  import_deps: [:let_me]
]
This ensures that mix format does not add unnecessary parentheses to the
LetMe macro calls for policy definitions.
Policy module
You define your authorization rules in a policy module using the LetMe macros.
These rules are compiled into Spek
expressions, and functions for both authorization checks and introspection are
defined.
For instance, this is how you could define a policy for a simple article CRUD
interface:
defmodule MyApp.Policy do
  use LetMe.Policy

  object :article do
    # Creating articles is allowed if the user role is `editor` or `writer`.
    action :create do
      allow role: :editor
      allow role: :writer
      desc "Create a new article"
    end

    # Viewing articles is always allowed, unless the user is banned.
    action :read do
      allow true
      deny :banned
      desc "Read an article"
    end

    # Updating an article is allowed if (the user role is `editor`) OR
    # (the user role is `writer` AND the article belongs to the user).
    action :update do
      allow role: :editor
      allow [:own_resource, role: :writer]
      desc "Update an article"
    end

    # Deleting an article is allowed if the user is an editor.
    action :delete do
      allow role: :editor
      desc "Delete an article"
    end
  end
end
You can work with a single policy module, or you can define one policy module
for each of your contexts.
While this example uses Role-Based Access Control (RBAC), LetMe does not make
any assumptions about your access control model. You can define your
authorization rules in any way you see fit.
Check module
Authorization rules are based on the subject (usually the current user), the
object on which the action is performed, and the action itself (the verb). LetMe
does not enforce a particular authorization model or check implementation.
The checks passed to LetMe.Policy.allow/1 reference functions in your own
check module (by default __MODULE__.Checks; in this example,
MyApp.Policy.Checks). Each function in your check module should
accept the subject, the object, and optionally an extra argument. If no options
are passed to allow or deny (e.g. deny :banned), the check function must
be a 2-arity function. If an option is passed (e.g. allow role: :writer), the
function must be a 3-arity function. All check functions must return a boolean,
an :ok or :error tuple, :ok, or :error (see Spek.result/0).
For the policy example provided earlier, a corresponding check module could look
like this:
defmodule MyApp.Policy.Checks do
  alias MyApp.Accounts.Scope
  alias MyApp.Accounts.User

  @doc """
  Returns `true` if the `banned` flag is set on the user.
  """
  def banned(%Scope{user: %User{banned: banned}}, _), do: banned

  @doc """
  Checks whether the user ID of the object matches the ID of the current user.

  Assumes that the object has a `:user_id` field.
  """
  def own_resource(
    %Scope{user: %User{id: id}},
    %{user_id: id}
  ) when is_binary(id), do: true
  def own_resource(_, _), do: false

  @doc """
  Checks whether the user role matches the role passed as an option.

  ## Usage

      allow role: :editor

  or

      allow {:role, :editor}
  """
  def role(%Scope{user: %User{role: role}}, _object, role), do: true
  def role(_, _, _), do: false
end
Note the usage of the Scope struct. This is a struct defined in your
application that contains the current user and any additional information
needed for policy decisions, like the remote IP address or the
authenticator assurance level (AAL).
The usage of the Scope struct is in line with a new feature of the Phoenix
generators introduced in Phoenix 1.8. You could also use the User struct
directly, but basing authorization rules on a Scope struct will make it
easier to update your application later if your authorization requirements
become more complex.
Callbacks
Adding use LetMe.Policy to the start of your policy module will generate
several functions from the authorization rules:
	Authorization functions: See LetMe.Policy.authorize/4,
LetMe.Policy.authorize!/4 and LetMe.Policy.authorize?/4.
	Introspection functions: See LetMe.Policy.list_rules/0,
LetMe.Policy.list_rules/1, LetMe.Policy.get_rule/1 and others.

Authorization
With the authorization rules and checks in place, you can authorize user actions
wherever needed. A natural place are the functions in your context modules. This
way, authorization checks are part of your business logic, and they will be
applied independently from the interface that is used. For example, even if you
have a LiveView application, a REST API, and a GraphQL API, the authorization
checks will only have to be added once to the context modules.
A Blog context could like this:
defmodule MyApp.Blog do
  alias MyApp.Accounts.Scope
  alias MyApp.Blog.Article
  alias MyApp.Policy

  def list_articles(%Scope{} = scope) do
    with :ok <- Policy.authorize(:article_read, scope) do
      {:ok, Repo.all(Article)}
    end
  end

  def fetch_article(%Scope{} = scope, id) do
    with :ok <- Policy.authorize(:article_read, scope, id) do
      case Repo.get(Article, id) do
        nil -> {:error, :not_found}
        article -> {:ok, article}
      end
    end
  end

  def create_article(%Scope{} = scope, params) do
    with :ok <- Policy.authorize(:article_create, scope) do
      %Article{}
      |> Article.changeset(params)
      |> Repo.insert()
    end
  end

  def update_article(%Scope{} = scope, %Article{} = article, params) do
    with :ok <- Policy.authorize(:article_update, scope, article) do
      article
      |> Article.changeset(params)
      |> Repo.update()
    end
  end

  def delete_article(%Scope{} = scope, %Article{} = article) do
    with :ok <- Policy.authorize(:article_delete, scope, article) do
      Repo.delete(article)
    end
  end
end
Every context function takes the Scope struct as the first argument. Before
performing any actions on the articles, we first ensure the current user
is authorized to perform the intended action.
Error responses
By default, the LetMe.Policy.authorize/4 function returns
{:error, :unauthorized} if an authorization check fails.
iex> MyApp.Policy.authorize(:article_read, scope)
{:error, :unauthorized}
To obtain a LetMe.UnauthorizedError struct with the evaluated expression,
set the error option on LetMe.Policy to :detailed.
use LetMe.Policy, error: :detailed
To obtain a LetMe.UnauthorizedError struct without the evaluated expression,
set error option to :simple.
You can also override the default value at runtime:
iex> MyApp.Policy.authorize(:article_update, scope, object, error: :detailed)
{:error,
 %LetMe.UnauthorizedError{
   message: "unauthorized",
   expression: %Spek.AnyOf{
     children: [
       %Spek.Check{
         module: MyApp.Policy.Checks,
         fun: :role,
         args: [{:ctx, :subject}, {:ctx, :object}, :editor],
         result: false,
         satisfied?: false
       },
       %Spek.Check{
         module: MyApp.Policy.Checks,
         fun: :role,
         args: [{:ctx, :subject}, {:ctx, :object}, :writer],
         result: false,
         satisfied?: false
       }
     ]
   }
 }}

iex> MyApp.Policy.authorize(:article_update, scope, object, error: :simple)
{:error, %LetMe.UnauthorizedError{message: "unauthorized", expression: nil}}

iex> MyApp.Policy.authorize(:article_update, scope, object, error: :forbidden)
{:error, :forbidden}
Typespecs
LetMe automatically generates typespecs for the authorize functions in your
policy modules, which helps Dialyzer to ensure that only valid actions are
passed to the authorize functions.
Introspection
LetMe generates introspection functions for your authorization rules. This can
be useful if you want to render a documentation page, or if you want to show
a user's capabilities in their user profile.
iex> MyApp.Policy.list_rules()
[
  %LetMe.Rule{
    action: :create,
    expression: %Spek.AnyOf{
      children: [
        %Spek.Check{
          module: MyApp.Policy.Checks,
          fun: :role,
          args: [{:ctx, :subject}, {:ctx, :object}, :admin]
        },
        %Spek.Check{
          module: MyApp.Policy.Checks,
          fun: :role,
          args: [{:ctx, :subject}, {:ctx, :object}, :writer]
        }
      ]
    },
    description: "Create a new article",
    name: :article_create,
    object: :article,
    pre_hooks: [],
    metadata: []
  },
  # ...
]
To find a specific rule by its name:
iex> MyApp.Policy.get_rule(:article_create)
%LetMe.Rule{
  action: :create,
  expression: %Spek.AnyOf{
    children: [
      %Spek.Check{
        module: MyApp.Policy.Checks,
        fun: :role,
        args: [{:ctx, :subject}, {:ctx, :object}, :admin]
      },
      %Spek.Check{
        module: MyApp.Policy.Checks,
        fun: :role,
        args: [{:ctx, :subject}, {:ctx, :object}, :writer]
      }
    ]
  },
  name: :article_create,
  object: :article,
  # ...
}
To list all actions associated with a particular role (or any other check):
iex> MyApp.Policy.list_rules(check: {:role, :writer})
[
  %LetMe.Rule{
    action: :create,
    object: :article,
    # ...
  },
  %LetMe.Rule{
    action: :update,
    object: :article,
    # ...
  }
]
You can also define metadata on an action, which can be used to extend
the library's functionality.
For example, imagine you want to expose certain actions through your Absinthe
GraphQL schema while excluding others. You could achieve this by adding a
:gql_exclude key to the metadata.
defmodule GraphqlPolicy do
  use LetMe.Policy

  object :user do
    action :disable do
      allow role: :admin
      metadata :gql_exclude, true
    end
  end
end
iex> MyApp.Policy.get_rule(:user_disable)
%LetMe.Rule{
  action: :disable,
  expression: %Spek.Check{
    module: GraphqlPolicy.Checks,
    fun: :role,
    args: [{:ctx, :subject}, {:ctx, :object}, :admin]
  },
  description: nil,
  name: :user_disable,
  object: :user,
  pre_hooks: [],
  metadata: [
    gql_exclude: true
  ]
}
Scoped queries
Often, a user should have access to a certain resource type, but only to a
subset of the data. Consider a blog system: a user might be restricted to
viewing only published articles, unless they hold the role of a writer.
Similarly, in a system where users are part of specific companies, they might
only be allowed to see users from their own company.
To narrow down your queries based on the user type, implement the
LetMe.Schema.scope/3 callback of the LetMe.Schema behavior, typically within
your Ecto schema module.
defmodule MyApp.Blog.Article do
  use Ecto.Schema
  use LetMe.Schema

  import Ecto.Query
  alias MyApp.Accounts.User

  # Ecto schema and changeset

  @impl LetMe.Schema
  def scope(q, user, opts \\ nil)
  def scope(q, %User{role: :editor}, _), do: q
  def scope(q, %User{role: :writer}, _), do: q
  def scope(q, %User{}, _), do: where(q, published: true)
end
In this example, the Ecto query is modified to only return published articles,
unless the user is an editor or writer. The third argument can be utilized for
additional options.
With this setup, your list and fetch functions can be updated as follows:
def list_articles(%Scope{user: %User{} = current_user} = scope) do
  with :ok <- Policy.authorize(:article_read, scope) do
    articles =
      Article
      |> Article.scope(current_user)
      |> Repo.all()

    {:ok, articles}
  end
end

def fetch_article(%Scope{user: %User{} = current_user} = scope, id) do
  with :ok <- Policy.authorize(:article_read, scope, id) do
    result =
      Article
      |> where(id: ^id)
      |> Article.scope(current_user)
      |> Repo.one()

    case result do
      nil -> {:error, :not_found}
      article -> {:ok, article}
    end
  end
end
If you've worked with Bodyguard before,
this might look familiar. In Bodyguard,
you can find a Bodyguard.scope/2 function that derives the Ecto schema module
from the Ecto.Queryable and forwards the call to that module. In LetMe, you
need to call the scope/2 function of your Ecto schema directly. The behaviour
then only serves to enforce this pattern.
Field redactions
In certain scenarios, a user may be authorized to access a resource, but should
only see a subset of its fields. For instance, a user might be able to see
basic details of another user, such as name and avatar, but shouldn't see
sensitive information like email or phone number. One way to manage such cases
would be to conditionally show or hide specific information on the frontend.
However, a cleaner solution is to have your context functions omit sensitive
fields entirely.
To assist in these kinds of situations, the LetMe.Schema behaviour has another
callback: LetMe.Schema.redacted_fields/3.
defmodule MyApp.Accounts.User do
  use Ecto.Schema
  use LetMe.Schema

  alias MyApp.Accounts.User

  # Ecto schema and changeset

  @impl LetMe.Schema
  def redacted_fields(%User{}, %User{role: :admin}, _), do: []
  def redacted_fields(%User{id: id}, %User{id: id}, _), do: []
  def redacted_fields(%User{}, %User{}, _), do: [:email, :phone_number]
end
The LetMe.Schema.redacted_fields/3 function takes the object as the first
argument, the subject as the second argument, and an options argument. The
function should return a list of fields to redact.
In the example above, all fields are visible if the user has an 'admin' role, or
if the user being viewed (the object) is the same as the current user (the
subject). In other cases, the 'email' and 'phone_number' fields are hidden.
There are two strategies for handling field redactions:
	Modify the query to exclude the redacted fields.
	Redact the fields after retrieving the resource(s) from the database.

Modifying the query
One approach to field redaction involves adjusting the database query to
exclude redacted fields. Ecto's __schema__/1 function can retrieve the
non-virtual schema fields from your Ecto module. From this list, you can reject
any redacted fields and add a select clause that includes only the unredacted
fields.
def list_users(%Scope{user: %User{} = current_user}) do
  fields = User.__schema__(:fields)
  filtered_fields = LetMe.reject_redacted_fields(fields, %User{}, current_user)

  User
  |> select(^filtered_fields)
  |> Repo.all()
end
This method has the advantage of preventing the transfer of redacted fields from
the database. However, it also comes with several drawbacks:
	Decisions about which fields to select cannot be made based on data in the
struct. For instance, with the LetMe.Schema.redacted_fields/3 function
described earlier, we can ensure that admins can see all fields, but we
cannot guarantee that users can view all fields in their own user account.
	All redacted fields will appear as nil, and you won't be able to
distinguish between fields that were redacted and fields that are simply
empty. This distinction might be necessary for display in the frontend.
	More complex select clauses may not be compatible with this syntax.

Redacting the query result
To address the limitations of modifying the query, you can redact fields after
retrieving the data from the database. This can be done using the
LetMe.redact/3 function.
def list_articles(%User{} = current_user) do
  Article
  |> Repo.all()
  |> LetMe.redact(current_user)
end
The redact function can handle structs, lists of structs, and nil values.
Why use this library?
Consider using this library if:
	You're seeking an easy-to-read DSL for authorization rules that offers the
flexibility to implement your authorization checks as desired.
	You prefer to locate your authorization rules within your business layer,
thereby decoupling them from your interfaces.
	You'd like to centralize your authorization rules in one place (or one per
context).
	You want to generate a list of authorization rules.
	You need to filter your authorization rules, e.g., to identify which actions a
certain user role can perform.
	You're in need of a library that aids with query scopes and field redactions.
	You prefer a library with limited dependencies (LetMe depends on a single
library by the same author).

When not to use this library?
This library might not be the best fit if:
	You prefer to couple authorization checks with your interfaces.
	You favor using plugs or middlewares for authorization checks and require
ready-made solutions (though you can create your own plugs and middlewares
around this library's functions).
	You dislike DSLs and prefer to write functions directly (keep in mind, the DSL
only describes which checks to run and how to apply them; you'll still write
the actual checks as regular functions).
	Introspection isn't a priority for you.

Status
This library is actively maintained, but given its narrow feature set, you may
not see frequent updates. If you miss a feature or encounter an issue, don't
hesitate to open an issue.
Alternatives
For comparison, consider exploring these Elixir libraries:
	Canada
	Canary
	Bodyguard
	Speakeasy

The article
Authorization for Phoenix Contexts
may also be a helpful resource.


  

    Changelog

All notable changes to this project are documented in this file.
The format is based on
Keep a Changelog, and this project
adheres to Semantic Versioning.
Unreleased
3.0.4 - 2026-09-09
Changed
	Log the policy module and the check module in the message of the warning for a
rule that does not exist, instead of setting them as Logger metadata.

Fixed
	A policy module in which every rule evaluates to a literal true or false
produced warnings about clauses that will never match.
	A rule that evaluates to a literal true or false made the compiler warn
about branches on authorize?/4 in the calling module.

3.0.3 - 2026-08-26
Changed
	Require spek ~> 0.5.0.

3.0.2 - 2026-08-09
Changed
	Require spek ~> 0.4.0.
	Add the check module under the check_module key to the metadata of the
warning that is logged when a permission is checked for a rule that does not
exist.

Fixed
	The warning for a rule that does not exist logged the check module under the
policy_module metadata key. It logs the policy module now.

3.0.1 - 2026-06-05
Changed
	Require spek ~> 0.3.0.

3.0.0 - 2026-05-27
Added
	Add LetMe.Policy.fetch_expression/1.
	Add LetMe.Policy.fetch_expression!/1.
	Add LetMe.Policy.get_expression/1.

Changed
	Extract the expression structs, the evaluation logic and the optimization
logic introduced in LetMe 2.0.0 into a separate library called Spek, and use
that library instead.

How to upgrade
The DSL and callback functions are unchanged compared to version 2.0.0. Only
the representation of expressions under the expression key in the
LetMe.Rule and LetMe.UnauthorizedError structs was changed to use the
Spek structs.
	LetMe.AllOf -> Spek.AllOf
	LetMe.AnyOf -> Spek.AnyOf
	LetMe.Check -> Spek.Check
	LetMe.Literal -> Spek.Literal
	LetMe.Not -> Spek.Not

The structs have mostly the same structure, except for these differences:
	All structs: passed? -> satisfied?
	Spek.Literal: additional result key
	Spek.Check:	name -> fun
	additional module key, which contains the name of the check module.
	arg -> args
	Because of the way Spek maps the evaluation context to function arguments,
the args key holds a list in the format
[{:ctx, :subject}, {:ctx, :object}, arg], where arg is the value that
was previously under the arg key.



2.0.0 - 2026-03-31
Added
	Add LetMe.AllOf, LetMe.AnyOf, LetMe.Check, LetMe.Literal, and
LetMe.Not structs and t:LetMe.expression/0 type to represent policy
expressions.
	Add error option to use LetMe.Policy, LetMe.Policy.authorize/4 to
switch between error structs without evaluation details, error structs with
evaluation details, and arbitrary custom error values.
	Support check matcher function as argument for LetMe.filter_rules/2 and
LetMe.Policy.list_rules/1.

Changed
	Evaluate authorization checks lazily.
	Change LetMe.Policy.authorize/4 to always return an
{:error, LetMe.UnauthorizedError.t()} tuple when authorization checks
fail.
	Add expression field to LetMe.UnauthorizedError.t(), which contains the
policy expression and evaluation results until a decision was made.
	Replace allow and deny fields on LetMe.Rule struct with a single
expression field that contains a combined logical expression.
	Optimize the combined logical expression at compile time.
	Support check functions that return :ok, :error, {:ok, term}, or
{:error, term}. These return values can be read from the expression in the
LetMe.UnauthorizedError struct.
	Replace the allow and deny options in LetMe.filter_rules/2 and
LetMe.Policy.list_rules/1 with a single check option.

Removed
	Remove error_reason and error_message options from LetMe.Policy.

How to upgrade
Replace the error_reason and error_message options with the error option:
- use LetMe.Policy, error_reason: :forbidden, error_message: "Forbidden"
+ use LetMe.Policy, error: :forbidden
You can opt-in to detailed error structs by setting the value to :detailed
or simple error structs by setting the value to :simple.
use LetMe.Policy, error: :detailed
If you do that, change all pattern matches on {:error, :unauthorized} or your
custom error reason and update your type specifications accordingly.
@spec update_article(Scope.t(), Article.t(), map) ::
-   {:ok, Article.t()} | {:error, :unauthorized}
+   {:ok, Article.t()} | {:error, LetMe.Unauthorized.t()}
def update_article(scope, article, params)
  with MyApp.Policy.authorize(:article_update, scope, article) do
    # ...
  end
end

case update_article(scope, article, params) do
  {:ok, article} ->
    # ...

-   {:error, :unauthorized} ->
+   {:error, %LetMe.UnauthorizedError{}} ->
    # ...
end
Replace the allow and deny option in LetMe.filter_rules/2 and
LetMe.Policy.list_rules/1 with the check option. The value is unchanged.
- MyApp.Policy.filter_rules(allow: {:role, :admin})
+ MyApp.Policy.filter_rules(check: {:role, :admin})

- MyApp.Policy.filter_rules(deny: :suspended)
+ MyApp.Policy.filter_rules(check: :suspended)
If you were working directly with the allow and deny fields of the
LetMe.Rule struct, update your code to work with the expression field and
t:LetMe.expression/0 type instead.
1.2.5 - 2025-03-26
Changed
	Improve documentation.

1.2.4 - 2024-04-22
Fixed
	Redacting nested lists within structs resulted in a CaseClauseError.

1.2.3 - 2023-11-11
Changed
	Update documentation.

1.2.2 - 2023-06-28
Added
	Add error_message option to use LetMe.Policy to override the exception
message used by LetMe.Policy.authorize!/4, e.g.
use LetMe.Policy, error_message: "Not today, chap.".

1.2.1 - 2023-06-28
Added
	Define action type when you use LetMe.Policy.
	Add type specifications for generated authorize functions.

1.2.0 - 2023-06-19
Added
	Add an optional opts argument to the authorize functions, so that additional
options can be passed to pre-hooks.
	Support filtering by metadata in LetMe.filter_rules/2.

Changed
	Expect pre-hook options to be passed as a keyword list.

Fixed
	Fix deprecation warning about Logger.warn/2 in Elixir 1.15.

1.1.0 - 2023-05-08
Added
	Add a metadata macro to add metadata to actions. The metadata can be read
from the LetMe.Rule struct.

1.0.3 - 2023-03-21
Changed
	Update ex_doc and other dev dependencies.

1.0.2 - 2023-01-05
Added
	Add a cheat sheet for rules and checks.

Fixed
	A code example for rule introspection in the readme was wrong.

1.0.1 - 2022-11-06
Fixed
	LetMe.redact/3 raised a KeyError when you passed options without the
redact_value option.

1.0.0 - 2022-11-06
Added
	Add LetMe.Policy.filter_allowed_actions/3 and
LetMe.filter_allowed_actions/4.
	Add LetMe.Policy.get_object_name/1.

Changed
	Rename c:LetMe.Policy.authorized?/3 to c:LetMe.Policy.authorize?/3,
because consistency is more important than grammar, maybe.
	Replace the c:LetMe.Schema.scope/2 callback with LetMe.Schema.scope/3.
The __using__ macro defined default implementations for both functions that
returned the given query unchanged, in case you only needed the redact
callback of the behaviour. In practice, this made it all too easy to call the
2-arity version when only the 3-arity version was defined, and vice versa,
which would lead the query to not be scoped. So in order to reduce the room
for error at the cost of a minor inconvenience, you will now always need to
implement the 3-arity function, even if you don't need the third argument.
	Replace c:LetMe.Schema.redacted_fields/2 with
LetMe.Schema.redacted_fields/3 to allow passing additional options, and to
be consistent with LetMe.Schema.scope/3.

0.2.0 - 2022-07-12
Added
	Support nested field redactions, either by explicitly listing the fields or by
referencing a module that also implements LetMe.Schema.

Fixed
	reject_redacted_fields/3 called the redact/2 callback with the wrong
argument order.

0.1.0 - 2022-07-11
Added
	Initial release.



  

    Rules and Checks

Minimal example
Policy definition
Policy module
defmodule MyApp.Policy do
  use LetMe.Policy

  object :article do
    action :create do
      allow role: :writer
    end
  end
end
Check module
defmodule MyApp.Policy.Checks do
  def role(%MyApp.User{role: role}, _object, role), do: true
  def role(_, _, _), do: false
end
Context module
defmodule MyApp.Blog do
  alias MyApp.Blog.Article
  alias MyApp.Policy

  def create_article(params, %MyApp.User{} = current_user) do
    with :ok <- Policy.authorize(:article_create, current_user) do
      %Article{}
      |> Article.changeset(params)
      |> Repo.insert()
    end
  end
end
Check examples
Check without options
Policy module
object :article do
  action :create do
    allow :writer
  end
end
Check implementation
def writer(%MyApp.User{role: :writer}, _object), do: true
def writer(_, _), do: false
A check written as a bare atom is called with two arguments.
Check with options
Policy module
object :article do
  action :delete do
    allow trust_level: 50
  end
end
Check implementation
def trust_level(%MyApp.User{trust_level: actual_level}, _, required_level)
  when actual_level >= required_level,
  do: true

def trust_level(_, _, _), do: false
A check written as a {name, option} tuple is called with three arguments.
Check that depends on the object
Policy module
object :article do
  action :update do
    allow :own_resource
  end
end
Check implementation
def own_resource(%MyApp.User{id: user_id}, %{user_id: user_id}), do: true
def own_resource(_, _), do: false
Rule examples
Multiple actions with the same rules
object :article do
  action [:create, :update, :delete] do
    allow :admin
  end
end
Combine checks with AND
action :create do
  allow [:two_fa_enabled, role: :writer]
end
Combine checks with OR
action :create do
  allow role: :admin
  allow role: :writer
end
Conditionally allow with exception
action :create do
  allow :is_admin
  deny :is_suspended
end
Always allow
action :read do
  allow true
end
Always deny
action :read do
  deny true
end
Always allow with exception
action :read do
  allow true
  deny :user_is_suspended
end
Add description
action :create do
  desc "allows a user to create a new article"
  allow role: :writer
end
Pre-hooks
Without options
Policy module
object :article do
  action :create do
    pre_hooks :preload_roles

    allow role: :admin
    allow role: :editor
    allow role: :writer
  end
end
Check module
def role(%MyApp.User{roles: roles}, _object, role) do
  Enum.any?(roles, & &1.id == role)
end

def role(_, _, _), do: false

def preload_roles(subject, object) do
  {MyApp.Repo.preload(subject, [:roles]), object}
end
Every option except :error that you pass to an authorize function is appended
to the hook arguments. A hook registered without options is called with three
arguments as soon as the caller passes any option.
With options
Options are only accepted in the three-element form. The module has to be
named even when the hook is in the check module.
Policy module
object :article do
  action :create do
    pre_hooks {MyApp.Policy.Checks, :preload_roles, force: true}

    allow role: :admin
    allow role: :editor
    allow role: :writer
  end
end
Check module
def role(%MyApp.User{roles: roles}, _object, role) do
  Enum.any?(roles, & &1.id == role)
end

def role(_, _, _), do: false

def preload_roles(subject, object, opts) do
  {MyApp.Repo.preload(subject, [:roles], opts), object}
end
From a different module
object :article do
  action :create do
    pre_hooks {MyApp.Policy.Prehooks, :preload_roles}

    allow role: :admin
    allow role: :editor
    allow role: :writer
  end
end
Multiple pre-hooks
object :article do
  action :create do
    pre_hooks [:preload_roles, :role_list_to_role_id_list]

    allow role: :admin
    allow role: :editor
    allow role: :writer
  end
end
Metadata
object :article do
  action :create do
    allow role: :admin
    allow role: :editor
    allow role: :writer
    
    metadata :gql_exclude, true
    metadata :desc_ja, "ユーザーが新しい記事を作成できるようにする"
  end
end


  

    
LetMe 
    



      
LetMe is a library for defining and evaluating authorization rules and
handling query scopes and field redactions.
This module only defines auxiliary functions. The main functionality lies in
the LetMe.Policy module.

      


      
        Summary


  
    Functions
  


    
      
        filter_allowed_actions(rules, subject, object, policy)

      


        Takes a list of rules and only returns the rules that would evaluate to true
for the given subject and object.



    


    
      
        filter_rules(rules, opts)

      


        Takes a list of rules and a list of filter options and returns a filtered
list of rules.



    


    
      
        redact(struct, subject, opts \\ [])

      


        Takes a struct or a list of structs and redacts fields depending on the
subject (user).



    


    
      
        reject_redacted_fields(fields, object, subject, opts \\ [])

      


        Removes redacted fields from a given list of fields.



    





      


      
        Functions


        


  
    
      
    
    
      filter_allowed_actions(rules, subject, object, policy)



        
          
        

    

  


  

      

          @spec filter_allowed_actions([LetMe.Rule.t()], subject, object, module()) :: [
  LetMe.Rule.t()
]
when subject: any(), object: {atom(), any()} | struct()


      


Takes a list of rules and only returns the rules that would evaluate to true
for the given subject and object.
The object needs to be passed as a tuple, where the first element is the
object name, and the second element is the actual object, e.g.
{:article, %Article{}}.
If you registered the schema module with LetMe.Policy.object/3, you can
pass the struct without tagging it with the object name, e.g. %Article{}.
This function is used internally by LetMe.Policy.filter_allowed_actions/3.
Example
rules = MyApp.Policy.list_rules()

filter_allowed_actions(
  rules,
  %User{},
  {:article, %Article{}},
  MyApp.Policy
)

  



  
    
      
    
    
      filter_rules(rules, opts)



        
          
        

    

  


  

      

          @spec filter_rules(
  [LetMe.Rule.t()],
  keyword()
) :: [LetMe.Rule.t()]


      


Takes a list of rules and a list of filter options and returns a filtered
list of rules.
This function is used by LetMe.Policy.list_rules/1.
Filter options
	:object - Matches an object exactly.
	:action - Matches an action exactly.
	:check - Can be:	A check name as an atom
	A 2-tuple with the check name and the arg
	A 1-arity matcher function that takes a Spek.Check struct as an
argument and returns a boolean.


	:metadata - Either a metadata name as an atom or a 2-tuple with the
metadata name and the metadata value.

If an atom is passed as :check, all rules using the given check name are
returned, regardless of the argument the check is called with. If a 2-tuple
is passed, all rules are returned that use the given check with exactly that
argument. In either case, rules that have more checks in addition to the
given one will also be returned, and it does not matter whether the check
appears in an allow/1 or a deny/1 call.
Examples
iex> rules = [
...>   %LetMe.Rule{action: :create, name: :article_create, object: :article},
...>   %LetMe.Rule{action: :create, name: :category_create, object: :category}
...> ]
iex> filter_rules(rules, object: :article)
[%LetMe.Rule{action: :create, name: :article_create, object: :article}]

iex> rules = [
...>   %LetMe.Rule{
...>     action: :create,
...>     name: :article_create,
...>     object: :article,
...>     expression: %Spek.Check{
...>       module: MyApp.Policy.Checks,
...>       fun: :role,
...>       args: [{:ctx, :subject}, {:ctx, :object}, :editor]
...>     }
...>   },
...>   %LetMe.Rule{
...>     action: :update,
...>     name: :article_update,
...>     object: :article,
...>     expression: %Spek.AnyOf{
...>       children: [
...>         %Spek.Check{
...>           module: MyApp.Policy.Checks,
...>           fun: :own_resource,
...>           args: [{:ctx, :subject}, {:ctx, :object}]
...>         },
...>         %Spek.Check{
...>           module: MyApp.Policy.Checks,
...>           fun: :role,
...>           args: [{:ctx, :subject}, {:ctx, :object}, :writer]
...>         }
...>       ]
...>     }
...>   }
...> ]
iex> filter_rules(rules, check: :own_resource)
[
  %LetMe.Rule{
    action: :update,
    name: :article_update,
    object: :article,
    expression: %Spek.AnyOf{children: [
      %Spek.Check{
        module: MyApp.Policy.Checks,
        fun: :own_resource,
        args: [{:ctx, :subject}, {:ctx, :object}]
      },
      %Spek.Check{
        module: MyApp.Policy.Checks,
        fun: :role,
        args: [{:ctx, :subject}, {:ctx, :object}, :writer]
      }
    ]}
  }
]
iex> match?([_, _], filter_rules(rules, check: :role))
true
iex> filter_rules(rules, check: {:role, :editor})
[
  %LetMe.Rule{
    action: :create,
    name: :article_create,
    object: :article,
    expression: %Spek.Check{
      module: MyApp.Policy.Checks,
      fun: :role,
      args: [{:ctx, :subject}, {:ctx, :object}, :editor]
    }
  }
]
iex> filter_rules(rules, check: {:role, :writer})
[
  %LetMe.Rule{
    action: :update,
    name: :article_update,
    object: :article,
    expression: %Spek.AnyOf{
      children: [
        %Spek.Check{
          module: MyApp.Policy.Checks,
          fun: :own_resource,
          args: [{:ctx, :subject}, {:ctx, :object}]
        },
        %Spek.Check{
          module: MyApp.Policy.Checks,
          fun: :role,
          args: [{:ctx, :subject}, {:ctx, :object}, :writer]
        }
      ]
    }
  }
]

  



    

  
    
      
    
    
      redact(struct, subject, opts \\ [])



        
          
        

    

  


  

      

          @spec redact(struct(), any(), keyword()) :: struct()


          @spec redact([struct()], any(), keyword()) :: [struct()]


          @spec redact(nil, any(), keyword()) :: nil


      


Takes a struct or a list of structs and redacts fields depending on the
subject (user).
Uses the callback implementation for LetMe.Schema.redacted_fields/3 in the
struct module.
Options
	:redact_value - The value to be used for redacted fields. Defaults to
:redacted.

Any additional options will be passed to LetMe.Schema.redacted_fields/3.
Example
iex> article = %MyApp.Blog.Article{}
iex> user = %{id: 2, role: :user}
iex> redact(article, user)
%MyApp.Blog.Article{like_count: :redacted, title: "Give us back our moon dust and cockroaches", user_id: 1, view_count: :redacted}

iex> article = %MyApp.Blog.Article{}
iex> user = %{id: 2, role: :user}
iex> redact(article, user, redact_value: nil)
%MyApp.Blog.Article{like_count: nil, title: "Give us back our moon dust and cockroaches", user_id: 1, view_count: nil}

iex> articles = [
...>   %MyApp.Blog.Article{},
...>   %MyApp.Blog.Article{user_id: 2, title: "Joey Chestnut is chomp champ"}
...> ]
iex> user = %{id: 2, role: :user}
iex> redact(articles, user)
[%MyApp.Blog.Article{like_count: :redacted, title: "Give us back our moon dust and cockroaches", user_id: 1, view_count: :redacted}, %MyApp.Blog.Article{like_count: 25, title: "Joey Chestnut is chomp champ", user_id: 2, view_count: :redacted}]

  



    

  
    
      
    
    
      reject_redacted_fields(fields, object, subject, opts \\ [])



        
          
        

    

  


  

      

          @spec reject_redacted_fields([atom()], struct(), any(), keyword()) :: [atom()]


      


Removes redacted fields from a given list of fields.
Uses the LetMe.Schema.redacted_fields/3 callback implementation of the
struct module to determine the fields to remove.
Examples
iex> fields = [:like_count, :title, :user_id, :view_count]
iex> user = %{id: 1, role: :user}
iex> article = %MyApp.Blog.Article{}
iex> result = reject_redacted_fields(fields, article, user)
iex> Enum.sort(result)
[:like_count, :title, :user_id]
This can be useful as a safeguard to prevent accidentally casting fields the
user is not allowed to see and thereby nilifying or replacing them.
def update_changeset(%Article{} = article, attrs, %User{} = user) do
  fields = LetMe.reject_redacted_fields(
    [:title, :body, :internal_reference],
    article,
    user
  )

  article
  |> cast(attrs, fields)
  |> validate_required([:title, :body])
end
If a keyword list is given as a fourth argument, it is passed to
LetMe.Schema.redacted_fields/3.

  


        

      


  

    
LetMe.Policy behaviour
    



      
This module defines a DSL for authorization rules and compiles these rules
to authorization and introspection functions.
Usage
defmodule MyApp.Policy do
  use LetMe.Policy

  object :article do
    # Creating articles is allowed if the user role is `editor` or `writer`.
    action :create do
      allow role: :editor
      allow role: :writer
    end

    # Viewing articles is always allowed, unless the user is banned.
    action :read do
      allow true
      deny :banned
    end

    # Updating an article is allowed if (the user role is `editor`) OR
    # (the user role is `writer` AND the article belongs to the user).
    action :update do
      allow role: :editor
      allow [:own_resource, role: :writer]
    end

    # Deleting an article is allowed if the user is an editor.
    action :delete do
      allow role: :editor
    end
  end
end
use LetMe.Policy
When you use LetMe.Policy, the module will set @behaviour LetMe.Policy
and define all callback functions for that behaviour based on the macros
you use. It will also define an action type based your rules.
Options
use LetMe.Policy accepts two options, both of which are optional.
check_module
The module where the check functions are defined. Defaults to
__MODULE__.Checks.
error
If set to :detailed, LetMe.Policy.authorize/4 collects the
evaluated policy expressions and returns an
{:error, LetMe.UnauthorizedError.t()} tuple if the policy check fails.
If set to :simple, LetMe.Policy.authorize/4 returns an
{:error, LetMe.UnauthorizedError.t()} tuple without expression.
Any other value will be used unchanged in the error tuple.
While LetMe.Policy.authorize!/4 always raises a LetMe.UnauthorizedError
on error, the exception struct only contains the expression if error is
:detailed.
To prevent unnecessary work, it is recommended to only set the option to
:detailed if you do something with the collected expressions, e.g. for
logging policy decisions or to inform the user about why a policy check
failed.
It is also possible to override the default by passing the option directly to
the authorize functions.
The default value is :unauthorized.
Check module
The checks passed to allow/1 and deny/1 reference the names of functions
in the check module.
By default, LetMe tries to find the functions in __MODULE__.Checks (in the
example, this would be MyApp.Policy.Checks). However, you can override the
default check module:
use LetMe.Policy, check_module: MyApp.AuthChecks
Each check function has to take the subject (user), the object, and optionally
an additional argument, and must return a boolean value.
For example, this check determines whether a user is banned:
def banned(%User{banned: true}, _), do: true
def banned(%User{}, _), do: false
This check determines whether the user has the given role:
def role(%User{role: role}, _, role), do: true
def role(_, _, _), do: false
And this check determines whether the object belongs to the user:
def own_resource(%User{id: user_id}, %{user_id: user_id}), do: true
def own_resource(_, _), do: false
LetMe does not make any assumptions about your access control model, as long
as you can map your rules to subject, object and action. You can use the three
rules above with the allow/1 and deny/1 macros.
allow role: :admin
allow :own_resource
deny :banned
Combining checks
Rules evaluate to false by default. These rules will always be false
because they don't have any allow clauses:
action :create do
end

action :update do
  deny false
end
Trying to evaluate a rule name that does not exist also evaluates to false.
As soon as one deny check evaluates to true, the whole rule will evaluate
to false. This rule will always evaluate to false:
action :create do
  allow true
  deny true
end
If you pass a list of checks to either allow/1 or deny/1, the checks
are combined with a logical AND.
# false
action :create do
  allow [true, false]
end

# true
action :create do
  allow [true, true]
end

# true
action :create do
  allow [true, true]
  deny [true, false]
end

# false
action :create do
  allow [true, true]
  deny [true, true]
end
On the other hand, if either the allow/1 or the deny/1 macro is used
multiple times, the checks are combined with a logical OR.
# true
action :create do
  allow true
  allow false
end

# false
action :create do
  allow [true, false]
  allow false
end

# true
action :create do
  allow [true, false]
  allow true
end

# false
action :create do
  allow [true, true]
  allow true
  deny false
  deny true
end
Pre-hooks
You can use pre-hooks to process or gather additional data about the subject
and/or object before running the checks. This can be useful if you need to
preload associations or make external requests. Pre-hooks run once per
authorization request before running the checks. See the documentation for
pre_hooks/1.

      


      
        Summary


  
    Callbacks
  


    
      
        authorize(atom, any, any, keyword)

      


        Authorizes a request defined by the action, subject and object.



    


    
      
        authorize!(atom, any, any, keyword)

      


        Same as authorize/4, but raises an error if unauthorized.



    


    
      
        authorize?(atom, any, any, keyword)

      


        Same as authorize/4, but returns a boolean.



    


    
      
        fetch_expression(atom)

      


        Returns the expression of the rule with the given name. Returns an :ok tuple
or :error.



    


    
      
        fetch_expression!(atom)

      


        Returns the expression of the rule with the given name. Raises if the rule is
not found.



    


    
      
        fetch_rule(atom)

      


        Returns the rule for the given name. Returns an :ok tuple or :error.



    


    
      
        fetch_rule!(atom)

      


        Returns the rule with the given name. Raises if the rule is not found.



    


    
      
        filter_allowed_actions(list, subject, object)

      


        Takes a list of rules and only returns the rules that would evaluate to true
for the given subject and object.



    


    
      
        get_expression(atom)

      


        Returns the expression of the rule with the given name. Returns nil if the
rule is not found.



    


    
      
        get_object_name(module)

      


        Returns the object name for the given schema module or struct, if it was
registered using object/3.



    


    
      
        get_rule(atom)

      


        Returns the rule for the given rule name. Returns nil if the rule is
not found.



    


    
      
        get_schema(atom)

      


        Returns the schema module for the given object name, if it was registered
using object/3.



    


    
      
        list_rules()

      


        Returns all authorization rules as a list.



    


    
      
        list_rules(keyword)

      


        Same as list_rules/0, but takes a keyword list with filter options.



    





  
    Functions
  


    
      
        action(names, list)

      


        Defines an action that needs to be authorized.



    


    
      
        allow(checks)

      


        Defines the checks to be run to determine if an action is allowed.



    


    
      
        deny(checks)

      


        Defines the checks to be run to determine if an action is denied.



    


    
      
        desc(text)

      


        Allows you to add a description to a rule.



    


    
      
        metadata(key, value)

      


        Assigns metadata to the action in the form of a key value pair.



    


    
      
        object(name, module \\ nil, list)

      


        Defines an object on which actions can be performed.



    


    
      
        pre_hooks(hooks)

      


        Registers one or multiple functions to run in order to hydrate the subject
and/or object of the request.



    





      


      
        Callbacks


        


  
    
      
    
    
      authorize(atom, any, any, keyword)



        
          
        

    

  


  

      

          @callback authorize(atom(), any(), any(), keyword()) :: :ok | {:error, any()}


      


Authorizes a request defined by the action, subject and object.
Example
Assume we defined this authorization rule:
object :article do
  action :update do
    allow :own_resource
  end
end
And the :own_resource check is defined as:
def own_resource(%{id: user_id}, %{user_id: user_id}), do: true
def own_resource(_, _), do: false
The rule name consists of the object and the action name, in this case
:article_create. To authorize the action, we need to pass the rule name, the
subject (current user) and the object (the article to be updated).
This example assumes that the error option is set to :detailed
(see below).
iex> article = %{id: 80, user_id: 1}
iex> user_1 = %{id: 1}
iex> user_2 = %{id: 2}
iex> MyApp.Policy.authorize(:article_update, user_1, article)
:ok
iex> MyApp.Policy.authorize(:article_update, user_2, article)
{:error, %LetMe.UnauthorizedError{
  message: "unauthorized",
  expression: %Spek.Check{
    args: [{:ctx, :subject}, {:ctx, :object}],
    module: MyApp.Checks,
    fun: :own_resource,
    result: false,
    satisfied?: false
  }
}}
If the checks don't require the object, it can be omitted.
object :user do
  action :list do
    allow {:role, :admin}
    allow {:role, :client}
  end
end

iex> user = %{id: 1, role: :admin}
iex> MyApp.Policy.authorize(:user_list, user)
:ok
iex> user = %{id: 2, role: :user}
iex> MyApp.Policy.authorize(:user_list, user)
{
  :error,
  %LetMe.UnauthorizedError{
    expression: %Spek.AnyOf{
      children: [
        %Spek.Check{
        module: MyApp.Checks,
          fun: :role,
          args: [{:ctx, :subject}, {:ctx, :object}, :admin],
          result: false,
          satisfied?: false
        },
        %Spek.Check{
        module: MyApp.Checks,
          fun: :role,
          args: [{:ctx, :subject}, {:ctx, :object}, :client],
          result: false,
          satisfied?: false
        }
      ],
      satisfied?: false
    },
    message: "unauthorized"
  }
}
Error format
By default, {:error, :unauthorized} is returned if the policy check fails.
You can customize the error by passing the error option to the function.
MyApp.Policy.authorize(:article_update, scope, object, error: :forbidden)

{:error, :forbidden}
You can also set a default as an option for use LetMe.Policy (see module
documentation).
To obtain a LetMe.UnauthorizedError struct with detailed evaluation
information, set error: :detailed.
MyApp.Policy.authorize(:article_update, scope, object, error: :detailed)

%LetMe.UnauthorizedError{
  message: "unauthorized",
  expression: %Spek.AnyOf{
    children: [
      %Spek.Check{
        module: MyApp.Policy.Checks,
        fun: :role,
        args: [{:ctx, :subject}, {:ctx, :object}, :editor],
        result: false,
        satisfied?: false
      },
      %Spek.Check{
        module: MyApp.Policy.Checks,
        fun: :role,
        args: [{:ctx, :subject}, {:ctx, :object}, :writer],
        result: false,
        satisfied?: false
      }
    ]
  }
}
To obtain a LetMe.UnauthorizedError struct without the expression, set
error: :simple.
MyApp.Policy.authorize(:article_update, scope, object, error: :simple)

%LetMe.UnauthorizedError{
  message: "unauthorized",
  expression: nil
}
Additional options
All options except :error are passed into any pre_hooks defined on the
resource's policy. This can be used to dynamically pass additional
information.

  



  
    
      
    
    
      authorize!(atom, any, any, keyword)



        
          
        

    

  


  

      

          @callback authorize!(atom(), any(), any(), keyword()) :: :ok


      


Same as authorize/4, but raises an error if unauthorized.
Example
With the same authorization rules as defined in the authorize/4
documentation, we get this:
iex> article = %{id: 80, user_id: 1}
iex> user_1 = %{id: 1}
iex> user_2 = %{id: 2}
iex> MyApp.Policy.authorize!(:article_update, user_1, article)
:ok
iex> MyApp.Policy.authorize!(:article_update, user_2, article)
** (LetMe.UnauthorizedError) unauthorized
Error details
If you require detailed information about the performed checks under the
expression field in the LetMe.UnauthorizedError exception struct, you can
set the error option to :detailed.
MyApp.Policy.authorize!(:article_update, scope, object, error: :detailed)
With any other option values, the expression field will be nil.
You can also set the default error option on use LetMe.Policy (see module
documentation).

  



  
    
      
    
    
      authorize?(atom, any, any, keyword)



        
          
        

    

  


  

      

          @callback authorize?(atom(), any(), any(), keyword()) :: boolean()


      


Same as authorize/4, but returns a boolean.
Example
With the same authorization rules as defined in the authorize/4
documentation, we get this:
iex> article = %{id: 80, user_id: 1}
iex> user_1 = %{id: 1}
iex> user_2 = %{id: 2}
iex> MyApp.Policy.authorize?(:article_update, user_1, article)
true
iex> MyApp.Policy.authorize?(:article_update, user_2, article)
false

  



  
    
      
    
    
      fetch_expression(atom)


        (since 3.0.0)


        
          
        

    

  


  

      

          @callback fetch_expression(atom()) :: {:ok, Spek.expression()} | :error


      


Returns the expression of the rule with the given name. Returns an :ok tuple
or :error.
The rule name is an atom with the format {object}_{action}.
Example
iex> MyApp.Policy.fetch_expression(:article_create)
{:ok,
 %Spek.AnyOf{
   children: [
     %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :admin]},
     %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :writer]}
   ],
 }}

 iex> MyApp.Policy.fetch_expression(:cookie_eat)
 :error

  



  
    
      
    
    
      fetch_expression!(atom)


        (since 3.0.0)


        
          
        

    

  


  

      

          @callback fetch_expression!(atom()) :: Spek.expression()


      


Returns the expression of the rule with the given name. Raises if the rule is
not found.
The rule name is an atom with the format {object}_{action}.
Example
iex> MyApp.Policy.fetch_expression!(:article_create)
%Spek.AnyOf{children: [
  %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :admin]},
  %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :writer]}
]}

  



  
    
      
    
    
      fetch_rule(atom)



        
          
        

    

  


  

      

          @callback fetch_rule(atom()) :: {:ok, LetMe.Rule.t()} | :error


      


Returns the rule for the given name. Returns an :ok tuple or :error.
The rule name is an atom with the format {object}_{action}.
Example
iex> MyApp.Policy.fetch_rule(:article_create)
{:ok,
 %LetMe.Rule{
   action: :create,
   expression: %Spek.AnyOf{
     children: [
       %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :admin]},
       %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :writer]}
     ],
   },
   name: :article_create,
   object: :article,
   pre_hooks: []
 }}

 iex> MyApp.Policy.fetch_rule(:cookie_eat)
 :error

  



  
    
      
    
    
      fetch_rule!(atom)



        
          
        

    

  


  

      

          @callback fetch_rule!(atom()) :: LetMe.Rule.t()


      


Returns the rule with the given name. Raises if the rule is not found.
The rule name is an atom with the format {object}_{action}.
Example
iex> MyApp.Policy.fetch_rule!(:article_create)
%LetMe.Rule{
  action: :create,
  expression: %Spek.AnyOf{children: [
    %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :admin]},
    %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :writer]}
  ]},
  name: :article_create,
  object: :article,
  pre_hooks: []
}

  



  
    
      
    
    
      filter_allowed_actions(list, subject, object)



        
          
        

    

  


  

      

          @callback filter_allowed_actions([LetMe.Rule.t()], subject, object) :: [LetMe.Rule.t()]
when subject: any(), object: {atom(), any()} | struct()


      


Takes a list of rules and only returns the rules that would evaluate to true
for the given subject and object.
Examples
The object can be passed as a tuple, where the first element is the
object name, and the second element is the actual object, e.g.
{:article, %Article{}}.
iex> rules = MyApp.Policy.list_rules()
iex> MyApp.Policy.filter_allowed_actions(
...>   rules,
...>   %{id: 2, role: nil},
...>   {:article, %MyApp.Blog.Article{}}
...> )
[
  %LetMe.Rule{
    action: :view,
    expression: %Spek.Literal{result: true, satisfied?: true},
    description: "allows to view an article and the list of articles",
    name: :article_view,
    object: :article,
    pre_hooks: []
  }
]
If you registered the schema module with LetMe.Policy.object/3, you can
pass the struct without tagging it with the object name.
iex> rules = MyApp.Policy.list_rules()
iex> MyApp.Policy.filter_allowed_actions(
...>   rules,
...>   %{id: 2, role: nil},
...>   %MyApp.Blog.Article{}
...> )
[
  %LetMe.Rule{
    action: :view,
    expression: %Spek.Literal{result: true, satisfied?: true},
    description: "allows to view an article and the list of articles",
    name: :article_view,
    object: :article,
    pre_hooks: []
  }
]

  



  
    
      
    
    
      get_expression(atom)


        (since 3.0.0)


        
          
        

    

  


  

      

          @callback get_expression(atom()) :: Spek.expression() | nil


      


Returns the expression of the rule with the given name. Returns nil if the
rule is not found.
The rule name is an atom with the format {object}_{action}.
Example
iex> MyApp.Policy.get_expression(:article_create)
%Spek.AnyOf{
  children: [
    %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :admin]},
    %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :writer]}
  ]
}

iex> MyApp.Policy.get_expression(:cookie_eat)
nil

  



  
    
      
    
    
      get_object_name(module)



        
          
        

    

  


  

      

          @callback get_object_name(module()) :: atom() | nil


      


Returns the object name for the given schema module or struct, if it was
registered using object/3.
Examples
iex> MyApp.Policy.get_object_name(MyApp.Blog.Article)
:article

iex> MyApp.Policy.get_object_name(%MyApp.Blog.Article{})
:article

iex> MyApp.Policy.get_object_name(MyApp.Blog.Tag)
nil

  



  
    
      
    
    
      get_rule(atom)



        
          
        

    

  


  

      

          @callback get_rule(atom()) :: LetMe.Rule.t() | nil


      


Returns the rule for the given rule name. Returns nil if the rule is
not found.
The rule name is an atom with the format {object}_{action}.
Example
iex> MyApp.Policy.get_rule(:article_create)
%LetMe.Rule{
  action: :create,
  expression: %Spek.AnyOf{
    children: [
      %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :admin]},
      %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :writer]}
    ]
  },
  name: :article_create,
  object: :article,
  pre_hooks: []
}

iex> MyApp.Policy.get_rule(:cookie_eat)
nil

  



  
    
      
    
    
      get_schema(atom)



        
          
        

    

  


  

      

          @callback get_schema(atom()) :: module() | nil


      


Returns the schema module for the given object name, if it was registered
using object/3.
Examples
iex> MyApp.Policy.get_schema(:article)
MyApp.Blog.Article

iex> MyApp.Policy.get_schema(:user)
nil

  



  
    
      
    
    
      list_rules()



        
          
        

    

  


  

      

          @callback list_rules() :: [LetMe.Rule.t()]


      


Returns all authorization rules as a list.
Example
iex> MyApp.PolicyShort.list_rules() |> Enum.sort()
[
  %LetMe.Rule{
    action: :create,
    expression: %Spek.AnyOf{
      children: [
        %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :admin]},
        %Spek.Check{module: MyApp.Checks, fun: :role, args: [{:ctx, :subject}, {:ctx, :object}, :writer]}
      ]
    },
    name: :article_create,
    object: :article,
    pre_hooks: []
  },
  %LetMe.Rule{
    action: :update,
    expression: %Spek.Check{module: MyApp.Checks, fun: :own_resource, args: [{:ctx, :subject}, {:ctx, :object}]},
    name: :article_update,
    object: :article,
    pre_hooks: [:preload_groups]
  }
]

  



  
    
      
    
    
      list_rules(keyword)



        
          
        

    

  


  

      

          @callback list_rules(keyword()) :: [LetMe.Rule.t()]


      


Same as list_rules/0, but takes a keyword list with filter options.
See LetMe.filter_rules/2 for a list of available filter options.

  


        

      

      
        Functions


        


  
    
      
    
    
      action(names, list)


        (macro)


        
          
        

    

  


  

      

          @spec action(atom() | [atom()], Macro.t()) :: Macro.t()


      


Defines an action that needs to be authorized.
Within the do-block, you can use the allow/1, deny/1 and pre_hooks/1
macros to define the checks to be run and the desc/1 macro to add a
description.
This macro must be used within the do-block of object/2.
Each action block will be compiled to a rule. The rule name is an atom with
the format {object}_{action}.
Example
object :article do
  action :create do
    allow role: :editor
    allow role: :writer
  end

  action :update do
    allow role: :editor
    allow [:own_resource, role: :writer]
  end
end
If you have multiple actions with the same allow and deny rules, you can also
pass a list of action names as the first argument.
object :article do
  action [:create, :update, :delete] do
    allow role: :editor
    allow role: :writer
  end
end

  



  
    
      
    
    
      allow(checks)


        (macro)


        
          
        

    

  


  

      

          @spec allow(LetMe.Rule.check() | [LetMe.Rule.check()]) :: Macro.t()


      


Defines the checks to be run to determine if an action is allowed.
The argument can be:
	a function name as an atom
	a tuple with the function name and an additional argument
	a list of function names or function/argument tuples
	true or false - Always allows or denies an action. Can be useful in
combination with the deny/1 macro.

The function must be defined in the configured check module and take the
subject (current user), object as arguments, and if given, the additional
argument.
If a list is given as an argument, the checks are combined with a logical
AND.
If the allow/1 macro is used multiple times within the same action/2
block, the checks of each macro call are combined with a logical OR.
Examples
Let's assume you defined the following checks:
defmodule MyApp.Policy.Checks do
  def role(%User{role: role}, _, role), do: true
  def role(_, _, _), do: false

  def own_resource(%User{id: id}, %{user_id: id}, _), do: true
  def own_resource(_, _, _), do: false
end
This would allow the :article_update action only if the current user has
the role :admin:
object :article do
  action :update do
    allow role: :admin
  end
end
This is equivalent to:
object :article do
  action :update do
    allow {:role, :admin}
  end
end
This would allow the :article_update action if the user has the role
:writer and the article belongs to the user:
object :article do
  action :update do
    allow [:own_resource, role: :writer]
  end
end
This is equivalent to:
object :article do
  action :update do
    allow [:own_resource, {:role, :writer}]
  end
end
This would allow the :article_update action if
(the user has the role :admin or (the user has the role :writer and
the article belongs to the user)):
object :article do
  action :update do
    allow role: :admin
    allow [:own_resource, role: :writer]
  end
end

  



  
    
      
    
    
      deny(checks)


        (macro)


        
          
        

    

  


  

      

          @spec deny(LetMe.Rule.check() | [LetMe.Rule.check()]) :: Macro.t()


      


Defines the checks to be run to determine if an action is denied.
If any of the checks evaluates to true, the allow checks are overridden
and the authorization request is automatically denied.
If a list is given as an argument, the checks are combined with a logical
AND.
If the deny/1 macro is used multiple times within the same action/2
block, the checks of each macro call are combined with a logical OR.
Examples
Let's assume you defined the following checks:
defmodule MyApp.Policy.Checks do
  def role(%User{role: role}, _, role), do: true
  def role(_, _, _), do: false

  def own_resource(%User{id: id}, %{user_id: id}, _), do: true
  def own_resource(_, _, _), do: false

  def same_user(%User{id: id}, %User{id: id}, _), do: true
  def same_user(_, _, _), do: false
end
This would allow the :user_delete action by default, unless the object is
the current user:
object :user do
  action :delete do
    allow true
    deny :same_user
  end
end
This would allow the :article_update action only if the current user has
the role :admin, unless the object is the current user:
object :user do
  action :delete do
    allow role: :admin
    deny :same_user
  end
end
This would allow the :user_delete by default, unless the object is the
current user and the current user is an admin:
object :user do
  action :delete do
    allow true
    deny [:same_user, role: :admin]
  end
end
This would allow the :user_delete by default, unless the object is the
current user or the current user is a peasant:
object :user do
  action :delete do
    allow true
    deny :same_user
    deny role: :peasant
  end
end

  



  
    
      
    
    
      desc(text)


        (macro)


        
          
        

    

  


  

      

          @spec desc(String.t()) :: Macro.t()


      


Allows you to add a description to a rule.
The description can be accessed from the LetMe.Rule struct. You can use it
to generate help texts or documentation.
Example
object :article do
  action :create do
    desc "allows a user to create a new article"
    allow role: :writer
  end
end

  



  
    
      
    
    
      metadata(key, value)


        (macro)


        
          
        

    

  


  

      

          @spec metadata(atom(), term()) :: Macro.t()


      


Assigns metadata to the action in the form of a key value pair.
The metadata can be accessed from the LetMe.Rule struct. You can use it
to extend the functionality of the library.
Example
object :article do
  action :create do
    allow role: :writer

    desc "Allows a user to create a new article."
    metadata :desc_ja, "ユーザーが新しい記事を作成できるようにする"
  end
end
The LetMe.Rule struct returned by the introspection functions would look
like this:
%LetMe.Rule{
  action: :create,
  expression: %Spek.Check{
    module: MyApp.Policy.Checks,
    fun: :role,
    args: [{:ctx, :subject}, {:ctx, :object}, :writer]
  },
  description: "Allows a user to create a new article.",
  name: :article_create,
  object: :article,
  pre_hooks: [],
  metadata: [
    desc_ja: "ユーザーが新しい記事を作成できるようにする"
  ]
}
It is also possible to use the metadata macro multiple times.
object :article do
  action :create do
    allow role: :writer

    desc "Allows a user to create a new article."
    metadata :desc_ja, "ユーザーが新しい記事を作成できるようにする"
    metadata :desc_es, "Permite al usuario crear un nuevo artículo."
  end
end
This would result in:
%LetMe.Rule{
  action: :create,
  expression: %Spek.Check{
    module: MyApp.Policy.Checks,
    fun: :role,
    args: [{:ctx, :subject}, {:ctx, :object}, :writer]
  },
  description: "Allows a user to create a new article.",
  name: :article_create,
  object: :article,
  pre_hooks: [],
  metadata: [
    desc_ja: "ユーザーが新しい記事を作成できるようにする",
    desc_es: "Permite al usuario crear un nuevo artículo."
  ]
}

  



    

  
    
      
    
    
      object(name, module \\ nil, list)


        (macro)


        
          
        

    

  


  

      

          @spec object(atom(), module() | nil, Macro.t()) :: Macro.t()


      


Defines an object on which actions can be performed.
Within the do-block, you can use the action/2 macro to define the actions
and checks.
Examples
object :article do
  action :create do
    allow role: :writer
  end

  action :delete do
    allow role: :editor
  end
end
You can optionally pass the schema module as the second argument. The schema
module should implement the LetMe.Schema behaviour.
object :article, MyApp.Blog.Article do
  action :create do
    allow role: :writer
  end
end
At the moment, this doesn't do much, except that you can find the schema
module by passing the object name to get_schema/1, or find the object name
by passing the schema module or struct to get_object_name/1 now. Also,
you can now only pass the struct to filter_allowed_actions/3, without
explicitly passing the object name.

  



  
    
      
    
    
      pre_hooks(hooks)


        (macro)


        
          
        

    

  


  

      

          @spec pre_hooks(LetMe.Rule.hook() | [LetMe.Rule.hook()]) :: Macro.t()


      


Registers one or multiple functions to run in order to hydrate the subject
and/or object of the request.
This is useful if you need to enhance the data for multiple checks in the
same action by preloading associations, making external requests, or similar
things. The configured hook functions will be called once before running the
checks for an action.
The referenced functions must take the subject and object as arguments and
return a 2-tuple with the updated subject and object.
The referenced functions may also take an optional third argument that are
opts passed through the authorize functions. These opts are merged into
any opts that are specified in the pre_hook definition.
Examples
Let's assume we defined these check and hook functions in our check module:
def MyApp.Policy.Checks do
  # Checks

  def min_age(%{age: age}, _, min_age), do: age >= min_age

  # Hooks

  def double_age(subject, object) do
    new_subject = %{subject | age: subject.age * 2}
    {new_subject, object}
  end

  def set_age(subject, object, age: age) do
    new_subject = %{subject | age: age}
    {new_subject, object}
  end
end
If an atom is passed, LetMe will try to find the function in the check module.
object :article do
  action :view do
    pre_hooks :double_age
    allow min_age: 50
  end
end
With this in place, the following authorization request will evaluate to
true:
MyApp.Policy.authorize!(:article_view, %{age: 25})
# => true
If your hooks are defined in a different module, you can also pass a
module/function tuple. The pre-hook configuration above is equivalent to:
object :article do
  action :view do
    pre_hooks {MyApp.Policy.Checks, :double_age}
    allow min_age: 50
  end
end
You can also pass options to a hook by using an MFA tuple:
object :article do
  action :view do
    pre_hooks {MyApp.Policy.Checks, :set_age, age: 50}
    allow min_age: 50
  end
end

MyApp.Policy.authorize!(:article_view, %{age: 10})
# => true
You can achieve the same functionality dynamically using the opts on authorize!:
object :article do
  action :view do
    pre_hooks {MyApp.Policy.Checks, :set_age}
    allow min_age: 50
  end
end

MyApp.Policy.authorize!(:article_view, %{age: 10}, age: 50)
# => true
And finally, you can also pass a list of hooks, which will be run in sequence:
alias MyApp.Policy.Checks

object :article do
  action :view do
    pre_hooks [{Checks, :set_age, age: 25}, :double_age]
    allow min_age: 50
  end
end

MyApp.Policy.authorize!(:article_view, %{age: 10})
# => true

  


        

      


  

    
LetMe.Schema behaviour
    



      
Defines a behaviour with callbacks for scoping and redactions.
Using this module will define overridable default implementations for the
scope/3 and redacted_fields/3 callbacks.
Usage
defmodule MyApp.Blog.Article do
  use LetMe.Schema
  import Ecto.Schema
  alias MyApp.Accounts.User

  @impl LetMe.Schema
  def scope(q, user, opts \\ nil)
  def scope(q, %User{role: :admin}, _), do: q
  def scope(q, %User{}, _), do: where(q, published: true)

  @impl LetMe.Schema
  def redacted_fields(_, %User{role: :admin}, _), do: []
  def redacted_fields(%__MODULE__{user_id: id}, %User{id: id}, _), do: []
  def redacted_fields(_, %User{}, _), do: [:view_count]
end
use LetMe.Schema
When you use LetMe.Schema, the module will set @behaviour LetMe.Schema
and define default implementations for the functions scope/3 and
redacted_fields/3. Both functions are overridable.
Scoping a query
With the setup above, you can scope a blog article query depending on the
user.
defmodule MyApp.Blog do
  import Ecto.Query

  alias MyApp.Accounts.User
  alias MyApp.Blog.Article

  def list_articles(%User{} = current_user) do
    Article
    |> Article.scope(current_user)
    |> Repo.all()
  end

  def get_article(id, %User{} = current_user) when is_integer(id) do
    Article
    |> where(id: id)
    |> Article.scope(current_user)
    |> Repo.one()
  end
end
Redacting fields
After implementing the redacted_fields/3 callback, you can hide fields
from depending on the user by calling LetMe.redact/3 on a struct or a list
of structs.
def list_articles(%User{} = current_user) do
  Article
  |> Repo.all()
  |> LetMe.redact(current_user)
end

        redacted_fields()

      


    





  
    Callbacks
  


    
      
        redacted_fields(object, subject, opts)

      


        Returns the fields that need to be removed from the given object for the given
subject.



    


    
      
        scope(queryable, subject, opts)

      


        Takes a queryable (usually an Ecto.Queryable) and a subject (usually the
current user) and returns an updated queryable.

          @type redacted_fields() :: [atom() | {atom(), module() | redacted_fields()}]

      redacted_fields(object, subject, opts)



        
          
        

    

  


  

      

          @callback redacted_fields(object, subject, opts) :: redacted_fields()
when object: any(), subject: any(), opts: keyword()


      


Returns the fields that need to be removed from the given object for the given
subject.
This function can be used to hide certain fields depending on the current
user. See also LetMe.redact/3 and LetMe.reject_redacted_fields/3.
defmodule MyApp.Blog.Article do
  use LetMe.Schema
  alias MyApp.Accounts.User

  @impl LetMe.Schema
  # hide view count unless the user is an admin or the article was written
  # by the user
  def redacted_fields(_, %User{role: :admin}, _), do: []
  def redacted_fields(%__MODULE__{user_id: id}, %User{id: id}, _), do: []
  def redacted_fields(_, %User{}, _), do: [:view_count]
end
The return value must be a list of fields to redact. You can also redact
nested fields by passing the field names directly:
[:email, sibling: [:phone_number]]
Or you can pass the module name of a nested struct, if that module also
implements LetMe.Schema:
[:email, sibling: MyApp.Relative]
The last argument can be used for any additional options.

  



  
    
      
    
    
      scope(queryable, subject, opts)



        
          
        

    

  


  

      

          @callback scope(queryable, subject, opts) :: queryable
when queryable: any(), subject: any(), opts: any()


      


Takes a queryable (usually an Ecto.Queryable) and a subject (usually the
current user) and returns an updated queryable.
This allows you to add WHERE clauses to a query depending on the user. For
example, you may want to add a WHERE clause to only return articles that are
published, unless the user is an admin. Or you may want to only return
objects that belong to the user.
defmodule MyApp.Blog.Article do
  use Ecto.Schema
  use LetMe.Schema

  import Ecto.Schema
  alias MyApp.Accounts.User

  # Ecto schema and changeset

  @impl LetMe.Schema
  def scope(q, user, opts \\ nil)
  def scope(q, %User{role: :admin}, _), do: q
  def scope(q, %User{}, _), do: where(q, published: true)
end
Since LetMe does not depend on Ecto and does not make any assumptions on the
queryable passed to the callback function, you are not constrained to use this
mechanism for Ecto queries only. For example, you could use the function to
add filter parameters before passing them to a filter function or making an
API call.
@impl LetMe.Schema
def scope(q, user, opts \\ nil)

def scope(query_params, %User{role: :admin}, _), do: query_params

def scope(query_params, %User{}, _) do
  Keyword.put(query_params, :published, true)
end
You can use the third argument to pass any additional options.

  


        

      


  

    
LetMe.Rule 
    



      
A struct for an authorization rule.

    Types
  


    
      
        check()

      


        A check references a function in the configured check module.



    


    
      
        hook()

      


        A hook can be registered to hydrate the subject and/or object before passing
them to the check functions.



    


    
      
        t()

      


        Struct for an authorization rule.

          @type check() :: atom() | {atom(), any()}


      


A check references a function in the configured check module.
Can be either one of:
	A function name as an atom. The function must be a 2-arity function that
takes the subject (usually the current user) and the object as
arguments.
	A tuple with the function name as an atom and a value of any type. The
function must be a 3-arity function that takes the subject, the object, and
the given value as arguments.

          @type hook() :: atom() | {module(), atom()} | {module(), atom(), keyword()}


      


A hook can be registered to hydrate the subject and/or object before passing
them to the check functions.
"Hydration" in this context means enriching or preparing the data by adding
or transforming necessary information. For instance, you might fetch related
data from the database, calculate derived properties, or format the data in a
certain way.
A hook can be one of the following:
	The name of a function defined in the configured check module as an atom.
	A {module, function} tuple.
	A {module, function, options} tuple, where the options are a keyword list.

In either case, the function must take the subject as the first argument, the
object as the second argument, and return a tuple with the updated subject and
object. If an MFA tuple is passed, the options are appended as a third
argument. The same happens when options are passed to the authorize functions,
so a hook registered without options is called with three arguments whenever
the caller passes any option.

          @type t() :: %LetMe.Rule{
  action: atom(),
  description: String.t() | nil,
  expression: Spek.expression(),
  metadata: Keyword.t(),
  name: atom(),
  object: atom(),
  pre_hooks: [hook()]
}


      


Struct for an authorization rule.
	action - The action (verb) to be performed on the object, e.g. :update.
	expression - A logical expression to determine whether the action is
allowed.
	description - A human-readable description of the action.
	name - The name of the rule. Is always {object}_{action}.
	object - The object that the action is performed on, e.g. :article.
	pre_hooks - Functions to run in order to hydrate the subject and/or object
before running the expression.
	metadata - A list of relevant metadata useful for extending functionality.


  


        

      


  

    
LetMe.UnauthorizedError exception
    



      
Raised by LetMe.Policy.authorize!/4 if a request is unauthorized.

      


      
        Summary


  
    Types
  


    
      
        t()

      


        Struct returned or raised if an authorization check fails.



    





  
    Functions
  


    
      
        new(message \\ "unauthorized")

      


        Returns an error struct with the given message and without an expression.

          @type t() :: %LetMe.UnauthorizedError{
  __exception__: term(),
  expression: Spek.expression() | nil,
  message: String.t()
}


      


Struct returned or raised if an authorization check fails.
expression contains the parts of the policy expression that were evaluated
and their results. Checks are evaluated lazily. The evaluation order follows
the expression as Spek.optimize/1 rewrote it at compile time, which is not
the order the allow/1 and deny/1 calls were written in.
The expression reflects the checks until a decision is made, but it does not
reflect the complete authorization policy.

          @spec new(String.t()) :: t()


      


Returns an error struct with the given message and without an expression.
Examples
iex> LetMe.UnauthorizedError.new()
%LetMe.UnauthorizedError{message: "unauthorized", expression: nil}

iex> LetMe.UnauthorizedError.new("forbidden")
%LetMe.UnauthorizedError{message: "forbidden", expression: nil}

  


        

      


  OEBPS/dist/epub-4WIP524F.js
(()=>{var s=document.querySelector.bind(document),o=document.querySelectorAll.bind(document);function r(e){document.readyState!=="loading"?e():document.addEventListener("DOMContentLoaded",e)}var l="hll";window.addEventListener("exdoc:loaded",t);function t(){o("[data-group-id]").forEach(e=>{e.addEventListener("mouseenter",i),e.addEventListener("mouseleave",i)})}function i(e){let n=e.currentTarget,a=e.type==="mouseenter",c=n.getAttribute("data-group-id");n.parentElement.querySelectorAll(`[data-group-id="${c}"]`).forEach(u=>{u.classList.toggle(l,a)})}r(()=>{t()});})();




